CODEWITHSUNDEEP
functionlotus-noteslotusscript
user1064180
user1064180

Reputation:

LotusScript - Can anyone fix my function?

I'm trying to write a validation function that checks to see if an entry being added already exists in the dataset.

But the search doesn't pick it up - i can just keep entering the same appointment into the database.

If anyone can spot why my code isn't working, i'd appreciate the help.

Thanks

Public Function checkNewLocationRecordIsUnique As Boolean

Dim s As New NotesSession
Dim w As New NotesUIWorkspace
Dim db As NotesDatabase
Dim selectView As NotesView
Dim key(0 To 4) As Variant
Dim entry As NotesViewEntry
Dim entryIsNotUniqueMsg As String
Let entryIsNotUniqueMsg = "There is already an entry for this date/time. Please modify your entry's details or cancel the existing entry to continue."
Dim thisDoc As NotesDocument
Dim uiDoc As NotesUIDocument
Set uidoc = w.CurrentDocument
Set thisDoc = uidoc.Document

'get handle to database and check we've found the database
Set db = s.CurrentDatabase
If Not db Is Nothing Then

    'get handle to view to lookup field combination in
    Set selectView = db.GetView("allLocationRecordsByName")
    Call selectView.Refresh()

    If Not selectView Is Nothing Then

        'populate "key" - an array of variants - with fields to use as match criteria

    key(0) = thisDoc.PersonName
    key(1) = thisDoc.StartDate
    key(2) = thisDoc.EndDate
    key(3) = thisDoc.StartTime
    key(4) = thisDoc.EndTime
    Set entry = selectView.GetEntryByKey(thisDoc.key, True)

        'lookup the combination in the view to see if it already exists
        If entry Is Nothing Then
            MsgBox "No conflicting entry found! Record added.", 0, "Notice"

            'if it wasn't found then the record is unique so return true
            checkNewLocationRecordIsUnique = True
        Else
            'else the combination was found - but lets make sure that it's not this one
            '(this could happen if the user is editing an existing record)
            'compare uids of both thisDoc and the doc entry that was found

            If entry.document.UniversalID = thisDoc.UniversalID Then
                checkNewLocationRecordIsUnique = True
            MsgBox "An Entry Was Found, But It Was The Entry! Record added.", 0, "Notice"

                'else it WAS found as a separate document so the function returns false
            Else
                MsgBox entryIsNotUniqueMsg, 0, "Error: Entry Is Not Unique"
                    checkNewLocationRecordIsUnique = False  
            End If
        End If
    End If  
End If
End Function

Upvotes: 0

Views: 905

Answers (3)

Richard Schwartz
Richard Schwartz

Reputation: 14628

You are using five lines of code to populate a local variant array called key, but you are not actually using that array for your GetEntryByKey call.

So my guess is that you want the code to say this:

Set entry = selectView.GetEntryByKey(key, True)

instead of this:

Set entry = selectView.GetEntryByKey(thisDoc.key, True)

Upvotes: 2

Jon McAuliffe
Jon McAuliffe

Reputation: 3157

Is the view allLocationRecordsByName sorted on each column included in the search key?

See GetEntryByKey documentation.

Upvotes: 0

Jasper Duizendstra
Jasper Duizendstra

Reputation: 2617

thisDoc.PersonName returns an array, you probably need to use

key(0) = thisDoc.PersonName(0)
key(1) = thisDoc.StartDate(0)
key(2) = thisDoc.EndDate(0)
key(3) = thisDoc.StartTime(0)
key(4) = thisDoc.EndTime(0)

Upvotes: 3

Related Questions