CODEWITHSUNDEEP
lotus-noteslotus-dominolotusscript
Johan G
Johan G

Reputation: 1013

Using multiple values field in Lotus Notes

I am trying to write a logging system for a form in Lotus Notes but I am at the part where I am not sure how I can append the information about the fields that are changed in the log fields. There are 3 fields that I use Log_Date (date), Log_User and Log_Actions (Text, allow multiple values).

I thought if I add comma to the log field it will create a new line when displaying the form but I am still getting a type mismatch on the case 2 line.

How can I append the new values to the log fields?

Sub Querysave(Source As Notesuidocument, Continue As Variant)
    ' Compare the values in the form after it is saved with its original values when the document is not a new document.    
    Dim doc As NotesDocument
    Set doc = Source.Document

    Dim session As New NotesSession
    Dim user As String
    user = session.CommonUserName

    If newDoc Then
        doc.Log_Date = Now()    
        doc.Log_User = user
        doc.Log_Actions = "New document created."
    Else        
        ' Load fields value to the array
        lastValues(0) = doc.QCR_No(0)
        lastValues(1) = doc.QCR_Mobile_Item_No(0)
        lastValues(2) = doc.QCR_Qty(0)

    ' Compared each value in the array to see if there is any difference
        Dim i As Integer
        For i = 0 To 2
            If lastValues(i) <> originalValues(i) Then
                Select  Case i
                Case 2 : doc.Log_Actions = doc.Log_Actions & "," & "Field QCR_Qty is changed"
                End Select
            End If
        Next
    End If
End Sub

Upvotes: 0

Views: 5100

Answers (3)

Sam DeNies
Sam DeNies

Reputation: 11

Or, 

If (Not doc.HasItem("LogActions")) Then
  doc.LogActions = "Field QCR_Qty is changed"
Else
  doc.LogActions = ArrayAppend(doc.LogActions,"Field QCR_Qty is changed")
End If

This is equivalent to the NotesItem method by rhsatrhs, which you use is matter of preference.

Upvotes: 1

Richard Schwartz
Richard Schwartz

Reputation: 14628

In LotusScript back-end classes (e.g. NotesDocument, NotesItem), a multi-valued field is represented by an array with one value per element of the array. For setting the value of a field, doc.Log_Actions is shorthand (they call it 'extended syntax' in the Domino Designer help) for assigning the first (i.e., zero subscript) element of the array, but that does not work for getting the value. To get the first value, you have to use doc.Log_Actions(0). To get or set the second value, you have to use doc.Log_Actions(1).

So, your Case 2 code could look like this:

doc.Log_Actions(1) = "Field QCR_Qty is changed"

My guess, however, is that you really want to be able to continually append to the end of the list of values each time this code runs. You are also going to want your code to be robust and not blow up on you if (for any reason!) the Log_Actions item does not exist in the document. For that, you are going to want to do this:

dim actionsItem as NotesItem
if doc.hasItem("Log_Actions") then
   set actionsItem = doc.getFirstItem("Log_Actions")
   call actionsItem.AppendToTextList("Field QCR_Qty is changed")
end if

Upvotes: 2

Jasper Duizendstra
Jasper Duizendstra

Reputation: 2617

doc.Log_Actions returns the notesitem. To access the value you need to use doc.Log_Actions(0)

Upvotes: 2

Related Questions