CODEWITHSUNDEEP
xsltxslt-1.0
Strontium_99
Strontium_99

Reputation: 1803

Using substring in xsl

Following on from an earlier question, and this is more about xsl syntax. I want to split part of a URL variable into a new variable in xsl. This code works when the variable is sitting part way along a URL. EG: http://www.mysite.com/test.aspx?aVar=something&bVar=somethingMore&cVar=yetMoreStill

    <xsl:variable name="testVar" select="substring-after($url, 'bVar=')"/>
    <xsl:value-of select="substring-before($testVar, '&amp;')" />

The problem is the variable can sometime sit at the end of the URL (I have no control over this) EG: http://www.mysite.com/test.aspx?aVar=something&bVar=somethingMore

So the above code fails. Is there away I can allow for both occurrences? The end game is I'm just trying to get the value of bVar no matter where it sits within the URL. Thanks.

Upvotes: 3

Views: 22610

Answers (4)

Dimitre Novatchev
Dimitre Novatchev

Reputation: 243449

The currently accepted answer is generally wrong.

Try it with this URL:

http://www.mysite.com/test.aspx?subVar=something&amp;bVar=somethingMore

and you get the wrong result: something

This question was already answered... In case you read the answer you would just reuse it and get your QString from the produced result:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:param name="pUrl" select=
     "'http://www.mysite.com/test.aspx?subVar=something&amp;bVar=somethingMore'"/>

     <xsl:template match="/">
       <xsl:variable name="vrtfQStrings">
           <xsl:call-template name="GetQueryStringParams"/>
         </xsl:variable>

         bVar = "<xsl:value-of select="ext:node-set($vrtfQStrings)/bVar"/>"
     </xsl:template>

     <xsl:template name="GetQueryStringParams">
      <xsl:param name="pUrl" select="$pUrl"/>

          <xsl:variable name="vQueryPart" select=
          "substring-before(substring-after(concat($pUrl,'?'),
                                            '?'),
                          '?')"/>

          <xsl:variable name="vHeadVar" select=
           "substring-before(concat($vQueryPart,'&amp;'), '&amp;')"/>

           <xsl:element name="{substring-before($vHeadVar, '=')}">
             <xsl:value-of select="substring-after($vHeadVar, '=')"/>
           </xsl:element>

        <xsl:variable name="vRest" select="substring-after($vQueryPart, '&amp;')"/>

        <xsl:if test="string-length($vRest) > 0">
           <xsl:call-template name="GetQueryStringParams">
             <xsl:with-param name="pUrl" select=
             "concat('?', substring(substring-after($vQueryPart, $vHeadVar), 2))"/>
           </xsl:call-template>
        </xsl:if>
     </xsl:template>
</xsl:stylesheet>

When applied on any XML document (not used), this transformation produces the wanted, correct result:

     bVar = "somethingMore"

Upvotes: 3

Maestro13
Maestro13

Reputation: 3696

Try to make use of tokenize (available in XSLT 2.0) like the following:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" omit-xml-declaration="yes" method="xml" version="1.0"/>

    <xsl:template match="/">
        <xsl:variable name="test"><![CDATA[http://www.mysite.com/test.aspx?aVar=something&bVar=somethingMore&cVar=yetMoreStill]]></xsl:variable>
        <xsl:variable name="splitURL" select="tokenize($test,'&amp;')"/>
        <xsl:variable name="bvar" select="$splitURL[starts-with(.,'bVar')]"/>
        <out><xsl:value-of select="substring-after($bvar, 'bVar=')"/></out>
    </xsl:template>
</xsl:stylesheet>

Upvotes: 3

VMykyt
VMykyt

Reputation: 1629

How about the following workaround?

<xsl:variable name="testVar" select="substring-after($url, 'bVar=')"/>
<xsl:value-of select="substring-before(concat($testVar, '&amp;'), '&amp;')" />

Upvotes: 7

Lukasz
Lukasz

Reputation: 7662

Try this. This is XSLT 1.0:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema">

<xsl:template match="/">
    <xsl:call-template name="urlResolver">
        <xsl:with-param name="input" select="'http://www.mysite.com/test.aspx?aVar=something&amp;bVar=somethingMore'" />
    </xsl:call-template>
    <xsl:call-template name="urlResolver">
        <xsl:with-param name="input" select="'http://www.mysite.com/test.aspx?aVar=something&amp;bVar=somethingMore&amp;cVar=yetMoreStill'" />
    </xsl:call-template>
</xsl:template>

<xsl:template name="urlResolver">
    <xsl:param name="input" />
    <xsl:variable name="testVar" select="substring-after($input, 'bVar=')"/>
    <xsl:choose>
        <xsl:when test="contains($testVar, '&amp;')"><xsl:value-of select="substring-before($testVar, '&amp;')" /></xsl:when>
        <xsl:otherwise><xsl:value-of select="$testVar" /></xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Upvotes: 3

Related Questions