CODEWITHSUNDEEP
batch-filecmdutc
AlanF
AlanF

Reputation: 1601

How to get UTC time with windows batch file

I have been trying to find a way of getting a windows batch file to display the current UTC time when run. So in other words get the current amount of milliseconds since it was initiated in 1970.

Does anyone know how to do this.

Upvotes: 5

Views: 26048

Answers (3)

BJK
BJK

Reputation: 39

Alternative:

REM get UTC times:
for /f %%a in ('wmic Path Win32_UTCTime get Year^,Month^,Day^,Hour^,Minute^,Second /Format:List ^| findstr "="') do (set %%a)
Set Second=0%Second%
Set Second=%Second:~-2%
Set Minute=0%Minute%
Set Minute=%Minute:~-2%
Set Hour=0%Hour%
Set Hour=%Hour:~-2%
Set Day=0%Day%
Set Day=%Day:~-2%
Set Month=0%Month%
Set Month=%Month:~-2%
set UTCTIME=%Hour%:%Minute%:%Second%
set UTCDATE=%Year%%Month%%Day%

Upvotes: 1

David Geeraerts
David Geeraerts

Reputation: 79

wmic TIMEZONE get * /value

Sample Output

Bias=-480
Caption=(UTC-08:00) Pacific Time (US & Canada)
DaylightBias=-60
DaylightDay=2
DaylightDayOfWeek=0
DaylightHour=2
DaylightMillisecond=0
DaylightMinute=0
DaylightMonth=3
DaylightName=Pacific Daylight Time
DaylightSecond=0
DaylightYear=0
Description=(UTC-08:00) Pacific Time (US & Canada)
SettingID=
StandardBias=0
StandardDay=1
StandardDayOfWeek=0
StandardHour=2
StandardMillisecond=0
StandardMinute=0
StandardMonth=11
StandardName=Pacific Standard Time
StandardSecond=0
StandardYear=0

In this example, I want UTC information, so that when I output to log, I can insert UTC information:

wmic TIMEZONE get * /value | FIND /I "Description"

Now I want to parse the string:

(Note in .cmd script/program, use %%P, %P only for console)

FOR /F "tokens=2 delims==" %P IN ('wmic TIMEZONE get * /value ^| FIND /I "Description"') DO Echo %P> var_UTC.txt

Now I want to set a variable that contains UTC

SET /P $SYSTEM_UTC= < var_UTC.txt

Now I want to use variable when writing out to log

(Note how having it in a variable allows for control over text)

echo 2020-12-15 [INFO] %$SYSTEM_UTC% > program.log

You can check out my Github repo's for some complex programs

Upvotes: 0

Joey
Joey

Reputation: 354614

Using WMI:

for /f %%x in ('wmic path win32_utctime get /format:list ^| findstr "="') do set %%x

This will set the variables Day, DayofWeek, Hour, Minute, Month, Quarter, Second, WeekInMonth and Year which you can use, then.

You won't get a time with Unix epoch from Windows easily, though. If you have PowerShell you can use

[long]((date).touniversaltime()-[datetime]'1970-01-01').totalmilliseconds

which you can call from a batchfile via

powershell "..."

But in that case you could write your batch file in a real language anyway.

Upvotes: 13

Related Questions