CODEWITHSUNDEEP
for-loopbatch-filecmd
John Boe
John Boe

Reputation: 3621

How to add tabs to string in batch

I have this code, where I want to test "counting". Counting does not work.

Code:

set "Myvar=Hello"
set #=%MyVar%
set strlen=0
:loop
if defined # (set #=%#:~1%&set /A strlen += 1&goto loop)

echo LEN: %strlen%
SET /A tabscount=(40-%strlen%)/8
echo Tabs count: %tabscount%
echo counting...
FOR /L %%G IN (0,1,%%tabscount) DO echo %%G
pause

And second problem is I would like to add tabs to end of string Myvar so many times as the tabscount value is.

How to do the adding in DO block? Should something like this work? SET "tabs=% %" Or rather SET "Myvar.= "?

Edited: I repaired the %%tabscount

Upvotes: 0

Views: 1778

Answers (1)

dbenham
dbenham

Reputation: 130889

Your counting FOR /L loop is missing percents around the tabscount variable

FOR /L %%G IN (0,1,tabscount) DO echo %%G

To append tabs is no different than appending any other string. Tabs are difficult to differentiate from spaces simply by looking at the code. I recommend defining a TAB variable so you only have to worry about the tab literal in one place.

If you were just doing a single append, then you could simply use

set "TAB=   "
set "MyVar=%MyVar%%TAB%"

But you want to use a loop to append multiple tabs, and %MyVar% will only be expanded once within a loop. So you need to do something to access the current value within the loop. You have multiple options:

1) Use CALL SET to get an extra parse for each iteration: (relatively slow and potentially unsafe)

for /l %%G in (0 1 %tabscount%) do call set "MyVar=%%MyVar%%%TAB%"

2) Use a GOTO loop instead of FOR /L. The IF statement will be reparsed each iteration, so it will work. (relatively slow, but a bit safer than option 1)

:appendLoop
if %tabscount% gtr 0 (
  set "MyVar=%MyVar%%TAB%"
  set /a tabscount-=1
  goto :appendLoop
)

3) Use delayed expansion so that you get the value at execution time instead of parse time. (much faster and always safe)

setlocal enableDelayedExpansion
for /l %%G in (0 1 %tabscount%) do set "MyVar=!Myvar!%TAB%"

There are other variations.

Note that SET /A is the one situation where you do not need percents around numeric variables. There is nothing wrong with what you have, but you could also write the SET /A statement as

set /a tabscount=(40-strlen)/8

Upvotes: 2

Related Questions