CODEWITHSUNDEEP
perlcsvhash
Elvis
Elvis

Reputation: 318

Perl CSV to hash

I have a CSV file that contains comment text prior to the header row and data, which I would like to read in as a hash for further manipulation. The primary key have the hash will be a combination of two data values. How do I?

  1. Search for the header row using pattern 'index'
  2. Use header for keys
  3. Read in rest of file.

Example CSV

#
#
#
#
Description information of source of file.

index,label,bit,desc,mnemonic
6,370,11,three,THRE
9,240,23,four,FOR
11,120,n/a,five,FIV

Example desired hash

( '37011' => { 'index' => '6', 'label' => '370', 'bit' => '11', 'desc' => 'three', 'mnemonic' => 'THRE'}, '24023' => {'index' => '9', 'label'  => '240', 'bit' => '23', 'desc' => 'four', 'mnemonic' => 'FOR'}, '120n/a' => {'index' => '11', 'label'  => '120', 'bit' => 'n/a', 'desc' => 'five', 'mnemonic' => 'FIV'} )

Upvotes: 7

Views: 11460

Answers (4)

creaktive
creaktive

Reputation: 5220

You'll need the Text::CSV module for that:

#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;
use Text::CSV;

my $filename = 'test.csv';

# watch out the encoding!
open(my $fh, '<:utf8', $filename)
    or die "Can't open $filename: $!";

# skip to the header
my $header = '';
while (<$fh>) {
    if (/^index,/x) {
        $header = $_;
        last;
    }
}

my $csv = Text::CSV->new
    or die "Text::CSV error: " . Text::CSV->error_diag;

# define column names    
$csv->parse($header);
$csv->column_names([$csv->fields]);

# parse the rest
while (my $row = $csv->getline_hr($fh)) {
    my $pkey = $row->{label} . $row->{bit};
    print Dumper { $pkey => $row };
}

$csv->eof or $csv->error_diag;
close $fh;

Upvotes: 12

Will Sheppard
Will Sheppard

Reputation: 3479

Text::CSV::Simple has existed since 2005...

From the docs:

# Map the fields to a hash
my $parser = Text::CSV::Simple->new;
$parser->field_map(qw/id name null town/);
my @data = $parser->read_file($datafile);

...simple!

Upvotes: 2

Erik Aronesty
Erik Aronesty

Reputation: 12945

simple, pasteable parser

sub parse_csv {
    my ($f, $s, %op) = @_;  # file, sub, options
    my $d = $op{delim}?$op{delim}:"\t";  # delimiter, can be a regex
    open IN, $f; 
    $_=<IN>; chomp;
    my @h=map {s/"//g; lc} split /$d/; # header assumed, could be an option
    $h[0]="id" if $h[0] eq ""; # r compatible
    while(<IN>) {
        chomp;
        my @d=split /$d/;
        map {s/^"//; s/"$//;} @d; # any file with junk in it should fail anyway
        push @h, "id" if (@h == (@d - 1)); # r compat
        my %d=map {$h[$_]=>$d[$_]} (0..$#d);
        &{$s}(\%d);
    }
}

example usage:

parse_csv("file.txt", sub {
   die Dumper $_[0];
})

note that stuff like $., and $_ still work in the sub

Upvotes: 1

William Pursell
William Pursell

Reputation: 212604

You could always do something like:

#!/usr/bin/env perl

use strict;
use warnings;

my %hash;
while( <DATA> ){ last if /index/ } # Consume the header
my $labels = $_;  # Save the last line for hash keys
chop $labels;
while(<DATA>){
    chop;
    my @a = split ',';
    my $idx = 0;
    my %h = map { $_ => $a[$idx++]} split( ",", $labels );
    $hash{ $a[1] . $a[2] } = \%h;
}

while( my ( $K, $H ) = each %hash ){
    print "$K :: ";
    while( my( $k, $v ) = each( %$H ) ) {
        print $k . "=>" . $v . "  ";
    }
    print "\n";
}

__DATA__

#
#
#
#
Description information of source of file.

index,label,bit,desc,mnemonic
6,370,11,three,THRE
9,240,23,four,FOR
11,120,n/a,five,FIV

Upvotes: 3

Related Questions