CODEWITHSUNDEEP
windowsbatch-filefor-loopcmd
arnobpl
arnobpl

Reputation: 1216

"continue" equivalent command in nested loop in Windows Batch

I have a batch file which contains nested loop with continue-like command:

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        if %%i gtr %%j goto CONTINUE
        test.exe 0 %%i %%j 100000 > "%%i_%%j".txt
        :CONTINUE
        rem
    )
)

But when if statement is true for the first time, it does not iterate further. I only get text files upto 1_256.txt. So it seems that goto CONTINUE has a problem. What is wrong with my batch file?

Upvotes: 17

Views: 30915

Answers (3)

Maverick
Maverick

Reputation: 1

A user-friendly option is to add an IF "ISCONTINUE" layer:

SETLOCAL ENABLEDELAYEDEXPANSION

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (

                SET ISCONTINUE=
                if %%i gtr %%j SET ISCONTINUE=1
                SET !ISCONTINUE! NEQ "1" (


                test.exe 0 %%i %%j 100000 > "%%i_%%j".txt


                )

    )
)

Upvotes: 0

aschipfl
aschipfl

Reputation: 34909

goto :Label inside of a block of code () like a for loop breaks the block context, so everything after the :Label is treated as being outside of the block. So you need to invert the if condition to not need goto as ths's answer demonstrates, or you place the code fragment with goto and :Label into a subroutine and use call like this:

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        call :SUB %%i %%j
    )
)
exit /B

:SUB outer inner
if %1 gtr %2 goto CONTINUE
test.exe 0 %1 %2 100000 > "%1_%2.txt"
:CONTINUE
rem
exit /B

Upvotes: 22

ths
ths

Reputation: 2942

it seems what you are actually trying to accomplish is a poor man's "less or equal than".
In this case, why not use the real "less or equal than", which is LEQ?
Additionally, you seem to want the output of test.exe in the "%%i_%%j".txt file, so don't use echo.

So this would be

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        if %%i LEQ %%j test.exe 0 %%i %%j 100000 > "%%i_%%j".txt
    )
)

Upvotes: 7

Related Questions