CODEWITHSUNDEEP
gnuplot
David Partridge
David Partridge

Reputation: 363

Getting plot title and caption data from the data file

Consider the following file that I want to plot using gnuplot: Servos20211222_105253.csv

# Date/Time 2021/12/22, 10:52:53
# PonE=0,LsKp=200,LsKi=0,LsKd=250,HsKp=40,HsKi=0,HsKd=130,Sp=800,TDEC=1175137
#
# Rel. Time, currentPos, PosPID, currentSpeed, speedPID, Lag, ServoPos
0.00000,4693184,0,0,0,0,4693184
0.00000,4693184,2300,0,368,0,4693184
0.00391,4693185,2300,12,367,0,4693184
 :
 :

I would like to:

I have some influence over the format of the header records, so if (for example) it would be better that they were not comments but provided in some other way, then that can be done.

Upvotes: 0

Views: 1152

Answers (2)

theozh
theozh

Reputation: 25734

There are ways with gnuplot only, although sometimes a bit cumbersome compared with using tools which you have available on Linux (or comparable tools which you need to install on Windows).

Update: shorter and "simplified" script

One possible gnuplot-only way:

  • set commentschar to nothing, i.e. ''
  • assign the columns to variables and/or arrays, e.g. myDate, myTime, P[1..9].
  • Merge P[1..8] into a multi-line string Params by "mis"-using sum (check help sum)
  • Convert P[9] into a floating point number TDEC for plotting

Script: (modified the data a bit just for illustration)

### extract values from headers with gnuplot only
reset session

$Data <<EOD
# Date/Time 2021/12/22, 10:52:53
# PonE=0,LsKp=200,LsKi=0,LsKd=250,HsKp=40,HsKi=0,HsKd=130,Sp=800,TDEC=1175137
#
# Rel. Time, currentPos, PosPID, currentSpeed, speedPID, Lag, ServoPos
0.00000,1300000,0,0,0,0,4693184
0.00200,1200000,2300,0,368,0,4693184
0.00391,1100000,2300,12,367,0,4693184
EOD

set datafile separator comma commentschar '' 
array P[9]    # array to store parameters
stats $Data u ($0==0 ? (myDate=strcol(1)[3:], myTime=strcol(2)) : \
          sum [_i=1:9] (P[_i] = _i==1 ? strcol(_i)[3:] : strcol(_i) ,0 )) \
          every ::0::1 nooutput
set datafile commentschar      # set back to default

Params = P[1]
Params = (sum [_i=2:8] (Params=Params.sprintf("\n%s",P[_i]),0),Params)

set title sprintf("%s %s", myDate, myTime)
TDEC = real(P[9][6:])       # convert to real number
set label 1 at graph 0.02, first TDEC P[9] offset 0,-0.7
set label 2 at graph 0.02, graph 0.85 Params

plot $Data u 1:2 w lp pt 7 title "Data", \
     TDEC w l lc "red" title "Target"
### end of script

Result:

enter image description here

Upvotes: 0

DanielTuzes
DanielTuzes

Reputation: 2744

It is a common problem to get text values from files using only gnuplot. If you can use OS and shell dependent solutions, I'd suggest to use remove the comments from the file and try something like

set title "`head -1 Servos20211222_105253.csv`"

You can place text anywhere using set label <"label text">, where the label text can be the 2nd line from the file.

You can plot a straight line using plot:

p sin(x), 0.5 title "TDEC"

But instead of 0.5, you need to get the value using shell scripts again, e.g. the cut unix command.

Upvotes: 1

Related Questions